Требуется разработать микропроцессорную систему управления, предназначенную для использования на лесопильном заводе. Лесопильная установка имеет конвейер, который доставляет бревна к распилочным механизмам. Бревна лежат на ленте конвейера вдоль нее по одному на ширину ленты.

Искомая микропроцессорная система (в дальнейшем просто МП система) должна нести следующие функции и иметь свойства:

- Измерить диаметр каждого бревна, проходящего по конвейеру, и, если он не укладывается в рамки [20…50]см, то считать бревно бракованным и не подавать его на распилку;

- Измерить длину lбр каждого бревна и вычислить его объем Vi; суммируя объемы неотбракованных бревен, подсчитывать общий объем распиленной древесины VS;

- По включении питания МП система должна проводить самотестирование (POST – power on self test) и самоинициализацию;

- Система должна включать ОЗУ, ПЗУ, часы реального времени;

- Информация должна отображаться на восьми буквенно-цифровых индикаторах.

Цель курсовой работы – спроектировать аппаратную и программную части МП системы. Аппаратную основу системы составляет микропроцессор Z80 фирмы Zilog. В задачу курсовой работы не входит подробное проектирование приводов и других механизмов, однако их рассмотрение потребуется для написания управляющей программы.

Описание принципа действия системы

Общая структура

На рис. 1 изображена схема “вход-выход” МП системы.

Рис. 1 Структура “вход-выход” МП системы

Цифровые сигналы с датчиков диаметра и длины бревна поступают в систему, формируется сигнал отбраковки. Затем система, имитируя калькулятор, рассчитывает Vi и обновляет сумму VS, храня эти величины в памяти. В зависимости от двух кнопок управления индикацией (одна из них, будучи нажатой, переводит в отжатое положение другую) на индикаторах отображается VS или текущее время. Для начальной установки часов есть 2 кнопки управления таймером, увеличивающие на единицу часы и минуты. Имеется кнопка включения/выключения питания “Вкл”.

Обзор датчиков и способа отбраковки

Чтобы вычислить объем бревна Vi, МП система должна “знать” формулу для вычисления. Формула для расчета Vi (в предположении, что бревно – круглый цилиндр):

. (1)

Рис. 2 Конструкция датчиков и механизма отбраковки

Чтобы найти диаметр d и длину lбр, надо знать конструкцию датчиков (рис. 2).

Датчик диаметра устроен следующим образом: бревно, двигаясь по конвейеру, отклоняет пластину , вращающуюся на горизонтальной оси, на угол a. Этот угол через редуктор ‚ подается на ось переменного резистора. Переменный резистор Rd включен в потенциометрический датчик (рис.3). Напряжение Ud с этого датчика подается в МП систему, где оцифровывается с помощью АЦП.

Рис. 3 Потенциометрический датчик

Расчет диаметра идет по формуле:

d = h – lпл cos a, т.е. надо знать угол a. (2)

Микропроцессор же имеет лишь напряжение Ud. По нему надо рассчитать текущее сопротивление переменного резистора Rd (см. формулу на рис.3), из него найти угол поворота оси резистора, которому соответствует это текущее сопротивление, из него, зная передаточное отношение редуктора, определить a.

Примем следующие допущения:

- номинал Rдоб=1 КОм; номинал Rd (переменное)=5,1 КОм; напряжение питания датчика U=12 В. Примечание: при этом диапазон Ud составляет [0; 10]В.

- особенности конструкции – а именно крепления переменного резистора и передаточного отношения редуктора – таковы, что

если a=0 (пластина вертикальна), то текущее Rd =0;

если a=90° (пластина горизонтальна), то Rd =Rdmax =5,1 КОм (максимально).

Примечание: данное требование однозначно определяет передаточное отношение редуктора – оно будет равно i1-2=90°/amax, где amax – угловой диапазон поворота оси резистора в градусах (т.к. при повороте пластины на 90° ось резистора поворачивается на amax)

Это допущение означает, что угол a может быть вычислен из максимального значения переменного резистора как

- последнее допущение: пусть h=62,5см=0,625м; lпл=50см=0,5м.

Получается формула перехода от Ud к a:

(3)

Напряжение с датчика Ud в системе измеряется с помощью 10-разрядного АЦП, рассчитанного на максимальное входное напряжение 10,5 В. Микропроцессор читает с АЦП не напряжение в вольтах, а его код – число в диапазоне [0..3FFH]=[0..102310]. Поэтому формулу (3) надо изменить, преобразовав напряжение 12 вольт в такой же код, исходя из интервала дискретности АЦП. Он равен д=10,5/1023=1,026×10-2 В. Отсюда 12 вольт будет изображаться величиной 12/ д »1169 единиц.

Итоговая формула перехода от Ud к a:

[рад] (4)

Подставим числа в формулу для диаметра (2):

d = 0,625 – 0,5cos a (5)

Сделаем вывод. Микропроцессор для измерения диаметра делает такие шаги. Зная Ud в виде кода, находит угол a в радианах – формула (4). Зная a, находит диаметр d – формула (5).

Датчик длины бревна основан на двух фотоэлементах Фэл1 и Фэл2 (ƒ на рис.2), поставленных вдоль конвейера на расстоянии l=1м друг от друга и двух таймерах внутри микропроцессорной системы. Фотоэлементы регистрируют смену освещенности “свет–темнота” и “темнота–свет”. Принципиально замер длины основан на предположении, что скорость ленты конвейера v постоянна.

Таймеры замеряют два интервала времени:

T1 – период времени, в течение которого передний край бревна проползет от Фэл1 к Фэл2;

Т2 – период времени, в течение которого бревно полностью проползет Фэл1.

=> (6)

Фотоэлемент устроен следующим образом (рис. 4):

Рис.4 Принципиальная схема фотоэлемента

Лампа HL1 – обычная лампа накаливания, ее свет сфокусирован отражателем на “своем” светоприемнике. Если свет доходит до светоприемника (бревно не загораживает) то транзистор открыт, на выходе фотоэлемента низкий уровень (0), иначе (в темноте) на выходе высокий уровень (1). Выходы Фэл1 и Фэл2 являются входами МП системы.

Алгоритм измерения длины бревна будет таким. Последовательно:

если на Фэл1 перепад 0-1 (“свет–темнота”), то старт таймеров Т1, Т2;

если на Фэл2 перепад 0-1 стоп таймера Т1;

по перепаду Фэл1 1-0 (“темнота–свет ”) стоп таймера Т2;

рассчитать длину по формуле (6).

Отметим: если во время работы, когда бревно проходит мимо и загораживает один из фотоэлементов, конвейер остановится, то будет замерена неверная неправдоподобно большая длина, возможно, будет переполнение таймеров. Аналогично, если в момент включения питания МП системы бревно уже лежит на конвейере, то его длина не может быть измерена. Во избежание этих ситуаций надо: сделать невозможной остановку конвейера при включенной МП системе; в алгоритм самотестирования (POST) добавить проверку фотоэлементов на готовность (удостовериться, что их светоприемные части освещены).

Механизм отбраковки рассмотрим менее подробно. МП система должна лишь выдать сигнал логической “1” для бракованного бревна и “0” для нормального. Сигнал выдается в момент, когда задняя кромка бревна минует Фэл2 (по перепаду Фэл2 1-0). Далее он усиливается и подается на привод отбраковки. Привод (не вдаваясь в подробности) при наличии “1” на его входе поднимает вверх постоянно движущийся поперечный конвейер („ на рис. 2), и он сбрасывает бревно с основного конвейера.

Аппаратная часть микропроцессорной системы

Общие характеристики

Общая направленность предлагаемой конструкции системы характеризуется тем, что система ориентирована на работу с памятью, портами ввода-вывода и прерываниями. Подсистема прямого доступа у памяти вообще не используется, т.к. в ее использовании не возникло серьезной необходимости: при работе управляющей программы нет такого внешнего устройства, которое бы вело интенсивный обмен данными с памятью.

Структура системы приведена на рис. 5.

Рис.5 Структура микропроцессорной системы

Ниже следуют пояснения по каждому блоку рис.5.

Блок центрального процессора, память и шины системы

“Сердцем” всей МП системы является микропроцессор (МП) Z80 (или его отечественный аналог – КР1856ВМ1).

Вкратце опишем используемые в МП системе выводы микропроцессора.

Сигналы, которые активны в нуле, будем отмечать суффиксом “#”.

- CLK – вход тактовой частоты 4 МГц;

- RESET# – вход сброса (активен в нуле);

- MREQ# – выход запроса памяти. Нулевое состояние свидетельствует, что микропроцессор обращается к памяти для чтения или записи;

- IORQ# – выход запроса портов ввода/вывода. Нулевое состояние означает, что идет обращение к портам;

- RD# – чтение. Активен, когда микропроцессор инициирует операцию чтения из памяти или из устройства ввода/вывода;

- WR# – запись. То же, что и RD#, но для операции записи;

- A0-A15 – шина адреса. Имеет 16 линий и используется для адресации к максимум 65535 ячейкам памяти и устройствам ввода-вывода;

- D0-D7 – шина данных. Восемь двунаправленных линий, используемых, для ввода/вывода данных микропроцессора, памяти и периферийных устройств.

- INT# – вход прерывания. Нуль на этом входе означает наличие запроса на прерывание от внешнего устройства.

- M1# – выход первого машинного цикла. Нуль на этом выходе показывает, что микропроцессор производит выборку кода операции. В нашей системе этот выход совместно с IORQ# служит для подтверждения прерывания.

Тактовым генератором служит мультивибратор, собранный на двух инверторах. Времязадающими цепями являются конденсатор, сопротивления и резонатор. Частота генератора 16 МГц (как и резонатора Z1). Затем эта частота двумя триггерами делится на 4, получается тактовая частота 4 МГц, которая и подается на вход CLK. Деление частоты нужно для большей ее точности.

Кнопка “RESET” в нажатом состоянии подает на соответствующий вход микропроцессора сигнал сброса. Для устранения эффекта “дребезга контактов” сигнал RESET# подается через D-триггер, записываясь в него по фронту первого же тактового импульса с линии CLK.

Для организации шин адреса (ША), данных (ШД), управления (ШУ) микропроцессорной системы к соответствующим выходам микропроцессора подключены буферные элементы. Их нагрузочная способность гораздо больше нагрузочной способности выводов микропроцессора. Они являются повторителями и “цифровыми усилителями” сигналов микропроцессора. Для ША это два 8-разрядных регистра ИР82. Для ШД – специальная микросхема – 8-разрядный двунаправленный шинный формирователь с возможным Z-состоянием выводов.

Четыре сигнала управления (WR#, RD#, MREQ#, IORQ#) сначала подвергаются дешифрации. Объединенные по схеме ИЛИ сигналы RD# и MREQ# дают в результате сигнал MEMRD# чтения памяти. Аналогично получены сигналы чтения порта IORD# и записи в порт IOWR#. Еще получен сигнал WR#/RD, который равен 0, когда активен сигнал WR# и равен 1, когда активен RD#. Пять сигналов (MEMRD#, MREQ#, WR#/RD, IORD#, IOWR#) понадобятся при организации обращения к памяти и портам. Все они объединены в 5-разрядную шину управления (ШУ), которая также имеет шинный формирователь.

Рассмотрим подключение микросхем памяти. Всего подключено 2К ПЗУ на одной микросхеме К541РЕ1 (адресное пространство 0000H – 07FFH) и 4К ОЗУ на двух микросхемах К537РУ8 (адреса 0800H – 17FFH). Принцип работы микропроцессора с памятью следующий. В первом такте машинного цикла обращения к памяти (чтения или записи) процессор выдает на ША адрес запрашиваемой ячейки. Этот адрес дешифруется так, что вход CS (выбор кристалла) соответствующей адресу микросхемы становится активным (нулем), сигнализируя, что эта микросхема выбрана для операции. Во втором такте МП формирует на шине управления сигналы управления. Сигнал MEMRD# подается на вход разрешения операции микросхемы ПЗУ. Сигнал WR#/RD подается на одноименные входы микросхем ОЗУ, а сигнал MREQ# – на вход разрешения операции микросхем ОЗУ. Итак, чтение/запись микросхемы памяти происходит, если одновременно выполнены два условия: микросхема выбрана адресом и ей разрешена операция сигналами управления.

Порты ввода-вывода

Всего МП система имеет 14 байт портов ввода и вывода. На рис. 5 можно видеть их адреса в пространстве ввода-вывода.

Механизм действия портов аналогичен действию микросхем памяти. Адрес порта на ША дешифруется в двенадцать сигналов выбора кристалла CS0#–CS13#, а каждый порт имеет возможность управляемого чтения/записи. Для порта ввода (порт диаметра) одновременно активные CSi# и IORD# стробируют выдачу одного байта на шину данных. Для порта вывода одновременно активные CSi# и IOWR# стробируют запись байта с шины данных в регистр порта.

Адреса портов ввода-вывода дешифруются отдельным дешифратором ИД3 с четырьмя входами и 16-ю выходами (первые 14 из которых – CS0#–CS13#). На входы подается младшая тетрада шины адреса – номер адресуемого порта, на всех выходах дешифратора образуются единицы, кроме одного нулевого выхода, имеющего этот номер.

Два адресам контроллера прерываний (0C-0D) дешифруются в один сигнал выборки кристалла, при этом контроллер принимает бит A0 адреса и самостоятельно разбирается, к какому из двух адресов идет обращение.

Порт ввода диаметра. Двухбайтный порт, выбирается адресами 00 и 01 (сигналами CS0# и CS1#). Датчик диаметра бревна является аналоговым. Чтобы ввести числовое значение диаметра в МП и использовать его в вычислениях, надо преобразовать напряжение с датчика в цифровой код. Этим занимается АЦП на специальной микросхеме К1113ПВ1А. Это 10-разрядный АЦП с выходными цифровыми уровнями ТТЛ с возможностью преобразования однополярного аналогового сигнала в диапазоне [0..10,5]В или биполярного сигнала в диапазоне [-5,5..5,5]В. Мы используем АЦП в однополярном режиме, поэтому вход 15 (Z1) присоединен к массе. Преобразуемое аналоговое напряжение подается на вход 13 (вход A). По заднему фронту (спаду) импульса на входе 11 (RES) АЦП сбрасывается и начинает преобразование. Преобразование занимает некоторое время (около 30 мкс). По окончании микросхема АЦП на выходах D0–D9 выводит итоговый цифровой код, а на выходе готовности данных 17 (RDY) выставляет логический 0, сигнализирующий “преобразование окончено”. На этом работа АЦП заканчивается.

Далее в МП системе сигнал с выхода АЦП RDY несет две функции: стробирует запись кода диаметра с АЦП в два буферных регистра ИР82 и посылает сигнал запроса прерывания на вход IR2 контроллера прерываний.

На вход RES АЦП мы подаем импульсы частотой Ѕ Гц, соответственно, раз в две секунды возникает прерывание IRQ2. Обработчик этого прерывания, при условии, что бревно сейчас под пластиной датчика (эта информацию можно прочесть из порта статуса фотоэлементов, описанного ниже) будет читать регистры диаметра в некий массив диаметров в ОЗУ. По прохождении бревна, когда запускается вычисление объема бревна, все введенные диаметры усредняются и в вычислениях используется среднее значение всех мгновенных диаметров.

Порт вывода сигнала отбраковки (адрес 02). Представляет собой обычный D-триггер. По одновременным сигналам CS2# и IOWR# в триггер записывается младший бит D0 шины адреса. Программа устанавливает D0=1, если бревно бракованное, иначе D0=0.

Порт вывода на индикаторы (8 байт). В эти ячейки программа заносит семисегментный код, выводимый на индикаторы. Сигналы выборки кристаллов индикаторов в схеме – CS3# (самый левый индикатор)…CS10# (самый правый).

Есть одна особенность индикации. На индикаторы возможен вывод объема VS или текущего времени – должно зависеть от кнопок управления индикацией на панели оператора. Пусть эти величины в семисегментном коде хранятся в разных ячейках памяти (каждая по 8 байт). Процессор, выполняя управляющую программу, то и дело копирует их содержимое в порт. Ячейку VS – в порт (03..0A), а ячейку времени – в порт (13..1A).

Как говорилось ранее, при обращении к портам дешифруются лишь младшие 4 бита с шины адреса. Поэтому и в том, и в другом случае обращение идет к одним и тем же физическим индикаторам. Дополнительной дешифрации, зависимой от кнопок управления индикации, подвергается бит A4 адреса. Если A4=1, значит, процессор пытается индицировать время, при этом нажатая кнопка “время” разрешает прохождение сигналов выборки кристалла. А в отжатом положении сигналы выборки не пройдут, и индикация не состоится. Аналогично нажатая кнопка “VS” разрешает адресацию к индикаторам при A4=0.

Этот вариант “двойной адресации” свою относительную сложность искупает экономией лишних 8-ми регистров, которые понадобились бы, если делать отдельные порты вывода для VS и для времени.

Порт ввода статуса фотоэлементов. Этот порт (адрес 0B) необходим для использования при первоначальном тестировании, когда система проверяет готовность фотоэлементов (контролирует выходы Фэл1 и Фэл2 на ноль). Во время работы содержимое порта несет смысл статуса обработки и помогает разобраться, на какой стадии своего движения находится бревно.

В порте действительно несут информацию только 2 бита: D0 – о состоянии Фэл1 (ноль на выходе Фэл1 или единица), D1 – о статусе Фэл2. Ноль свидетельствует об успешном прохождении света от лампы к светоприемнику фотоэлемента, единица – о том, что свет не проходит.

Порт контроллера прерываний (адреса 0C и 0D). Используется для адресации регистров контроллера: сигналы CS12# и CS13#, объединенные по ИЛИ, подаются на его вход выбора кристалла.

Подсистема прерываний

МП система должна периодически опрашивать датчики и оперативно реагировать на изменение их состояния. Один из вариантов опроса – МП в цикле управляющей программы опрашивает все датчики, анализирует их состояние; инициатива при вводе-выводе информации принадлежит микропроцессору. Второй вариант – опрос по прерываниям: само внешнее устройство, приготовив данные, подает к МП сигнал прерывания и тот считывает эти данные, выполняя процедуру обработки прерывания. Очевидно, что для нашей системы второй вариант преимуществен: медленно меняющийся диаметр лучше считывать по внешней периодической синхронизации (например, Ѕ Гц), чем в каждом цикле управляющей программы. Сигналы с фотоэлементов (точнее, их перепады, после которых надо производить старт/стоп таймеров), которые похожи на “исключительные ситуации”, также логичнее обрабатывать по прерываниям. Наконец, прерывания помогают организовать программно часы реального времени и таймеры T1 и T2, экономя на микросхемах. Недостаток только один: приходится усложнять систему, вводя программируемый контроллер прерываний (ПКП).

Опишем прерывания в МП системе.

1) IRQ0. Прерывание возникает по перепаду 0-1 на выходе фотоэлемента Фэл1. Обработчик должен сбросить и запустить таймеры T1 и T2.

2) IRQ1. Возникает по перепаду 1-0 на Фэл2 и означает, что измерения закончены, бревно полностью вышло из области действия датчиков. Обработчик должен рассчитать объем бревна Vi, суммарный объем VS и сформировать сигнал отбраковки.

3) IRQ2. Появляется по сигналу готовности данных на АЦП. Обработчик вводит 2 байта диаметра.

4) IRQ3. Источником служит генератор на 16 Гц. Обработчик делает инкремент часов реального времени и условный инкремент таймеров (анализируя информацию статуса):

	Если слово статуса ФЭЛ равно:
Инкремент T1	xxxxxx01
Инкремент T2	xxxxxx01 или xxxxxx11
Нет инкремента	иначе (xxxxxx00 или xxxxxx10)

5) IRQ4 и 6) IRQ5. Сигналы приходят от кнопок “+Час” и “+Мин” на панели оператора. Обработчик незамедлительно инкрементирует часы (минуты) реального времени.

6) Казалось бы, перепады на выходах фотоэлементов равноценны, и перепады сигналов 1-0 на Фэл1 и 0-1 на Фэл2 стоило бы тоже обрабатывать по прерываниям. Но это не нужно. Обработчики этих прерываний несли бы одну функцию: стоп того или другого таймера. А по прерыванию IRQ3 делается условный инкремент таймеров, т.е. таймер не надо останавливать, он остановится сам собой, когда сигналы с фотоэлементов придут в определенное сочетание (см. таблицу).

Сигналы запросов IRQi приходят на входы IR0–IR5 программируемого контроллера прерываний (запросы принимаются по переходу 0®1). Используется режим работы ПКП с фиксированными приоритетами прерываний. Максимальный приоритет имеет запрос IR0, минимальный – запрос IR5. На этом распределении приоритетов, кстати, основан выбор номеров для прерываний: чтобы прерывания, функционально более важные (от фотоэлементов и АЦП) имели больший приоритет, чем прерывания, несущие декоративный смысл (от часов и кнопок управления часами).

По выходу INT контроллер передает процессору запрос на прерывание. Процессор формирует сигналы подтверждения прерывания, приходящие на вход INTA контроллера.

Рассмотрим подключение остальных выводов. Контроллер будет работать в одиночном (не каскадном) режиме – это контролирует вывод SP=0 микросхемы.

На вход выбора кристалла CS подается дешифрованный адрес. На вход A0 подается нулевой разряд адреса. Выводы каскадирования CAS0–CAS2 остаются неподключенными. Выводы D0–D7 подключены к шине данных.

Перед работой ПКП нужно инициализировать. Управляющая программа делает это во время самотестирования системы. При инициализации нужно сообщить контроллеру адреса процедур обработки прерываний.

Программная часть микропроцессорной системы

Тестирующие программы

Тестовые программы запускаются сразу по включении питания микропроцессорной системы перед началом работы. Это тест ОЗУ, ПЗУ, тест фотоэлементов, инициализация программируемого контроллера прерываний, инициализация переменных системы.

Тест ОЗУ

Тест ОЗУ состоит в проверке всех ячеек ОЗУ на запись и верное считывание байтов 00Н и FFН. Если для какой-то ячейки совпадение записанного и прочитанного значений не состоялось, происходит переход на подпрограмму E_RAM, в регистровой паре HL при этом адрес неисправной ячейки.

Листинг 1: тест ОЗУ

; – – – тест ОЗУ (адреса 0800…17FF)

TST_RAM LD HL, 0800 ; HL¬начало области ОЗУ

TST_RAM1 XOR A ; A=0

LD (HL), A ; записать 0 в ячейку памяти

LD A, (HL) ; прочитать эту ячейку

OR A ;

JP NZ, E_RAM ; если в ячейке не ноль, то выход

CPL ; инвертировать A (A=FF)

LD (HL), A ; записать FF в ячейку памяти

LD A, (HL) ; прочитать эту ячейку

INC A ; если прочитано A=FF, то A=FF+1=0

JP NZ, E_RAM ; иначе выход

INC HL ; к следующему адресу

LD A, H ; проверить на достижение конца ОЗУ

CP #18 ;

JR NZ, TST_RAM1 ; конец цикла

… ; тест ОЗУ успешен, продолжение тестов

Подпрограмма E_RAM – это бесконечный цикл вывода на индикаторы признака ошибки ОЗУ (строки “Е1”) и адреса неисправной ячейки (например, “Е1 12AF”). Естественно, при этом дальнейшее выполнение управляющей программы и функционирование системы отменяется (поэтому переход на E_RAM выполняется командой JP, а не CALL). По адресу можно определить, какая именно (из двух) микросхема памяти подлежит замене.

Независимый от кнопок управления индикацией вывод на индикаторы семисегментным кодом производится через 8-байтный порт вывода 03..0A и через порт 13..1A одновременно (см. п.3.3). Адрес 0A (он же 1A) соответствует самому левому индикатору, адрес 03 (он же 13) – самому правому.

Декодирование из двоичного в семисегментный код делается с помощью массива перекодировки длиной 16 байт, расположенного в ПЗУ по начальному адресу 0700Н:

0700 3F 06 5B 4F 66 6D 7D 07 ; “0”–“7”

0708 7F 6F 77 7C 39 5E 79 71 ; “8”–“F”

Для декодирования шестнадцатиричной цифры в семисегментный код достаточно извлечь из массива элемент с индексом, равным этой цифре.

Важно то, что процедура E_RAM не обращается к памяти ни напрямую, ни через стек – она хранит все свои данные в регистрах и записывает только в порты индикаторов.

Листинг 2: процедура E_RAM, вызываемая после ошибки ОЗУ

; – – – обработка ошибки ОЗУ (код “E1”)

E_RAM EX DE, HL ; адрес-операнд из HL перенести в DE

LD H, #07 ; H¬старший байт адреса таблицы кодов

LD A, E ;

AND #0F ; выделяем младшую тетраду в E

LD L, A ; извлекаем элемент с этим номером из массива

LD C, (HL) ; в регистр C

; теперь C=код, посылаемый на 8-й индикатор

LD A, D ;

AND #0F ; выделяем младшую тетраду в D

LD L, A ;

LD B, (HL) ; теперь B=код, выводимый на 6-й индикатор

SRL D ; четырежды сдвигаем D вправо (0®D®CY)

SRL D ; заполняя старшие биты нулями

SRL D ;

SRL E ; четырежды сдвигаем E вправо (0®D®CY)

SRL E ; заполняя старшие биты нулями

SRL E ;

LD L, E ; теперь необходимости в наложении маски нет

LD E, (HL) ; E=код, выводимый на 7-й индикатор

LD L, D ;

LD D, (HL) ; D=код, выводимый на 5-й индикатор

; цикл вывода на индикаторы

E_RAM1 LD A, #79; A¬семисегментный код символа “E”

OUT (#0A), A ; в 1-й слева индикатор

OUT (#1A), A ;

LD A, #06 ; A¬“1”

OUT (#09), A ; во 2-й индикатор

OUT (#19), A ;

XOR A ; A¬“ ” (пусто)

OUT (#08), A ; в 3-й

OUT (#18), A ;

OUT (#07), A ; в 4-й

OUT (#17), A ;

LD A, D ; выводим DBEC на индикаторы 5678

OUT (#06), A ;

OUT (#16), A ;

LD A, B ;

OUT (#05), A ;

OUT (#15), A ;

LD A, E ;

OUT (#04), A ;

OUT (#14), A ;

LD A, C ;

OUT (#03), A ;

OUT (#13), A ;

JR E_RAM1 ; переход на начало цикла

Тест ПЗУ

Тест ПЗУ состоит в вычислении контрольной суммы ПЗУ, т.е. суммы всех байтов в ПЗУ без учета переполнения суммы, и сравнении полученной суммы с известным эталонным значением. Несовпадение свидетельствует о явной неисправности ПЗУ, совпадение не обязательно говорит об его исправности (могут быть, хотя маловероятно, две компенсирующие друг друга ошибки).

Для этого теста (чтобы знать эталон, с которым сравнивать) надо иметь все подпрограммы ПЗУ. Однако сейчас мы только на стадии заполнения постоянной памяти. Предлагается следующий путь: в составленной ниже программе теста ПЗУ вычисляем контрольную сумму и сравниваем ее с нулем. А после того, как запрограммируем ПЗУ полностью, последнюю ячейку ПЗУ (17FFН) оставим свободной и занесем в нее число, дополняющее сумму всего ПЗУ без последней ячейки до нуля.

Получив в сумме всех ячеек ПЗУ не ноль, программа тестирования вызывает зацикленную подпрограмму E_ROM, имея в регистре E число 2, характеризующее код ошибки.

Листинг 3: Тест ПЗУ

; – – – вычисление контрольной суммы ПЗУ

TST_ROM XOR A ; A=0

LD H, A ;

LD L, A ; HL=0

TST_ROM1 ADD A, (HL) ; A¬A+(HL)

INC HL ; увеличить адрес ПЗУ на 1

LD B, A ; сохранить сумму A на время

LD A, H ; и проверить, достигли ли конца ПЗУ

CP #08 ;

LD A, B ; восстановить сумму A

JR NZ, TST_ROM1;

OR A ; если конец ПЗУ, проверить A на ноль

LD E, 2 ;

JP NZ, E_ROM ;если не ноль, то ошибка ПЗУ

… ; иначе тест ПЗУ успешен, продолжаем тесты

Подпрограмма E_ROM выводит на два самых левых индикатора условный код ошибки ПЗУ (“E2”), а остальные индикаторы гасит. Индикация такой ошибки говорит о необходимости проверки и перепрограммирования микросхемы ПЗУ.

Листинг 4: процедура E_ROM, вызываемая после ошибки ПЗУ

; – – – обработка ошибки ПЗУ (код “E2”)

E_ROM LD A, #79 ; A¬“E”

OUT (#0A), A ;

LD A, E ; A¬код ошибки (2)

OUT (#09), A ;

XOR A ; A¬“0”

LD C, #08 ;

LD D, #18 ;

LD B, 6 ; счетчик

E_ROM1 OUT (C), A ; последние шесть индикаторов гасим

OUT (D), A ;

DEC C ;

DEC D ;

DJNZ E_ROM1 ;

JR E_ROM ;

Тест фотоэлементов

Перед началом работы нужно проверить прохождение света от ламп к фотоэлементам. Если один из фотоприемников не чувствует света, это значит, что или перегорела лампа фотоэлемента, или в момент пуска бревно уже лежит между фотоэлементами и его длина не может быть измерена, или повредился канал от фотоэлемента к процессору. В обоих случаях микропроцессорная система не начнет свою работу (т.к. нет возможности отличить второй случай от остальных). При обнаружении такой ошибки на индикаторы выводится признак ошибки фотоэлемента в виде условного кода “E3”.

В программе этого теста читается порт ввода статуса фотоэлементов (адрес 0B) и проверяются на ноль два его младших бита. Если хотя бы один не равен нулю, то происходит переход на обработчик ошибки. Причем для обработки ошибки можно использовать ту же процедуру E_ROM, перед вызовом загрузив в регистр E код ошибки 3 (экономия памяти).

Листинг 5: тест фотоэлементов

; – – – проверка двух младших битов порта ФЭЛ на 0

TST_FEL IN A, (#0B) ; прочесть слово статуса ФЭЛ

AND 3 ; наложить на него маску 000000112

LD E, 3 ;

JP NZ, E_ROM ; если не ноль, то ошибка

… ; иначе продолжаем тесты

Инициализация программируемого контроллера прерываний

Для инициализации контроллера надо переслать ему два управляющих слова ICW1 и ICW2, первое по адресу 0CН (A0=0), второе – по адресу 0DН (A0=1).

Пересылаются следующие управляющие слова:

Рис. 6 Применяемые управляющие слова инициализации ПКП

Слово ICW1 установит одиночный (без каскадного соединения) режим работы ПКП (бит 1), 4-хбайтный интервал для начальных адресов обработчиков прерываний (бит 2).

Биты 5–7 слова ICW1 вместе со всем словом ICW2 сообщат контроллеру, что первый обработчик (запроса IR0) начинается с адреса 0020Н.

Контроллер накладывает определенные ограничения на расположение обработчиков в памяти. Первое из них в том, подпрограммы обработки прерываний должны располагаться по порядку, начиная с адреса обработчика запроса IR0, и с постоянным интервалом, т.е. образовывать в памяти таблицу. Интервал расположения может составлять 4 байта (если бит 2 ICW1 равен единице, как в нашем случае), или 8 байт (если бит 2 равен нулю). При постоянном интервале адреса всех обработчиков определятся расположением первого (IR0).

Адрес первого обработчика составляется из полного слова ICW2 (старший байт) и битов 7,6,5 слова ICW1 (старшие три бита младшего байта адреса).

В нашем случае старший байт равен 00Н, младший байт равен 0010 0000 = 20Н. Обработчики имеют начальные адреса: 0020H, 0024H, 0028H, 002CH, 0030H, 0034H (6 обработчиков).

Процедура INI_PIC инициализирует контроллер.

Листинг 6: инициализация программируемого контроллера прерываний

; – – – переслать 38H в порт 0CH и 0 в порт 0DH

INI_PIC LD A, #38 ;

OUT (#0C), A ;

XOR A ;

OUT (#0D), A ;

Инициализация переменных системы

В системе за некоторыми ячейками памяти закреплена функция хранения переменных. Например, подсчитанный суммарный объем древесины VS в двоичном формате хранится в отдельных двух байтах памяти с адресами V_SUM, V_SUM+1.

Требуют инициализации только две переменные (инициализируются нулем):

VS (2 байта) – начальный адрес V_SUM;

Время (4 байта) – начальный адрес TIME.

Ясно, что эти имена (V_SUM и TIME) лишь условные обозначения (также, как, например, имена меток в листингах программ). При переводе в машинный код эти имена транслируются в двухбайтный адрес.

Листинг 7: инициализация ячеек суммарного объема и времени

; – – – начальное обнуление объема и времени

INI_VAR XOR A ;

LD (V_SUM), A ;

LD (V_SUM+1), A ;

LD (V_SUM+2), A ;

LD (TIME), A ;

LD (TIME+1), A ;

LD (TIME+2), A ;

LD (TIME+3), A ;

… ; следует продолжение переходит к основному циклу работы (описание см. в п.4.4).

Арифметические подпрограммы

Микропроцессорной системе необходимо “уметь” выполнять арифметические операции: сложение, вычитание, умножение, деление и косинус. В этом же разделе приведем и неарифметические процедуры для осуществления индикации: преобразования данных в двоично-десятичный код и в семисегментный.

Основным форматом чисел в МП системе является двухбайтный формат с фиксированной точкой вида 1байт , 1байт . Формат беззнаковый, предполагается, что числа положительны. Одно число умещается в одной регистровой паре. Минимальное представимое число – 0,01H=1/256=3,9×10-3, максимальное – FF,FFН=256,996.

Общие правила для всех вычислительных процедур:

- программист вызывающей программы сам следит, чтобы операнды и результат не выходили за пределы представления и чтобы при вычитании не образовалось отрицательных величин;

- операнды при сложении, вычитании, умножении, делении хранятся в регистровых парах HL и DE, результат в HL. Процедура косинуса получает операнд и выводит результат в паре HL.

Сложение

В микропроцессоре Z80 есть команда сложения регистровых пар ADD HL, DE. Однако, чтобы сохранить единообразие, оформим ее все же как подпрограмму.

Листинг 8: подпрограмма PLUS

; – – – подпрограмма сложения

; HL+DE®HL

; сохраняет A, BC, DE

PLUS ADD HL, DE ;

RET ;

Вычитание

В Z80 есть команда вычитания регистровых пар с учетом переноса SBC HL, DE. Используем ее в подпрограмме вычитания, обнулив прежде флаг CY.

Листинг 9: подпрограмма MINUS

; – – – подпрограмма сложения

; HL–DE®HL

; сохраняет A, BC, DE

MINUS OR A ; A не меняется, но флаг CY=0

SBC HL, DE ;

RET ;

Умножение

При умножении первый множитель хранится в паре BC (скопируем его туда из HL в начале), второй множитель хранится в DE. Результат первоначально получается в четырехбайтном виде HL.DE, затем “обрезается” до H.L.

Результат произведения накапливается в HLDE. В течение 16 циклов сдвигов HLDE второй множитель DE постепенно выдвигаясь, уходит вправо и на его место приходит из HL готовые биты произведения. Они получаются при суммировании первого множителя (BC) и левой половины накопленной суммы HLDE (HL). Суммирование делается в случае, если перед этим при сдвиге HLDE вправо из DE был выдвинут единичный бит.

Листинг 10: подпрограмма MUL

; – – – подпрограмма умножения

; HL´DE®HL

; все регистры меняются

MUL LD B, H ; BC=1-й множитель

LD C, L ;

LD HL, 0 ; HL=0

LD A, 16 ; счетчик цикла

MUL2 SRL H ; сдвиг 0®HLDE®CY

RR L ;

RR D ;

RR E ;

JR NC, MUL1 ; если выдвинут 0, то на конец цикла

ADD HL, BC ; если выдвинута 1, то сложить

MUL1 DEC A ;

JR NZ, MUL2 ;

LD H, L ; получено произведение HL.DE

LD L, D ; которое “обрезаем” до L.D и переносим в H.L

RET

Деление

При делении делимое хранится в HL, делитель в DE. Результат получается в виде трех байт [стек.L] (где “стек” – содержимое вершины стека), в конце программы младший байт стека переносится в H и окончательный результат имеет формат H.L. Регистровая пара BC в начале обнуляется.

Деление производится в течение 24-х циклов. В каждом цикле делается сдвиг BC¬HL¬0, т.е. делимое HL выдвигается влево в пару BC. Затем BC сравнивается с DE (путем вычитания BC–DE и проверки флага переноса). Если BC>DE, то младший разряд HL устанавливается единицей, в противном случае он остается нулем. Это один из разрядов частного.

После 16 сдвигов в делимое HL полностью сдвинется влево и на его место придет частное целочисленного деления, в BC будет остаток деления, DE сохранит делитель. На этом этапе целая часть частного в HL заносится в стек, а HL обнуляется. В оставшихся 8-ми сдвигах BC¬HL в BC будут сдвигаться только нули. После всех 24-х циклов в регистре L будет дробная часть частного, а в стеке целая часть.

Листинг 11: подпрограмма DIV

; – – – подпрограмма деления

; HL/DE®HL

; сохраняет DE, использует стек (2 байта)

DIV LD BC, 0 ;

LD A, 24 ; А – счетчик циклов

DIV4 PUSH AF ; сохранить счетчик А в стеке

ADD HL, HL ; BC¬HL¬0

RL C ;

RL B ;

LD A, C ;

SUB E ;

LD C, A ;

LD A, B ;

SBC D ;

Страницы: 1, 2